Public Function CheckAndCreateFolder(FolderName)
  fldr = Server.Mappath(FolderName)
  Set fso = CreateObject("Scripting.FileSystemObject")
  If Not fso.FolderExists(fldr) Then
    fso.CreateFolder(fldr)
  End If
  Set fso = Nothing
End Function

检查文件夹是否存在，不存在则创建文件夹，该函数无返回值。

例：Call CheckAndCreateFolder("ASP")

检查当前目录下是否存在ASP文件夹，不存在则创建文件夹ASP。

asp关于fso函数

'//提供文件处理通用接口
Class FileSystemObject
  '/*
  ' * 功能描述:删除文件
  ' * 输入参数：FileName——文件相对路径
  '*/
  Public Function DelFile(FileName)
     Dim getPath
     getPath="/"
     SET Fso=Server.CreateObject("Scripting.FileSystemObject")
     getPath=Replace(getPath&FileName,"//","/")
     if Fso.FileExists(Server.MapPath(getPath))=True then
      　　Fso.DeleteFile Server.mappath(getPath)
     End if
     Set Fso=Nothing
  End Function


  '/*
  ' * 功能描述:判断路径是否存在，如不存在则创建
  ' * 输入参数：SaveFilePath——相对路径,如：/UploadFiles/NewsFiles
  '*/
  Public Function CreatePath(SaveFilePath)
     Dim DeclarePath,FileObj,FilePath
     DeclarePath="/"
     Set FileObj=Server.CreateObject("Scripting.FileSystemObject")
     For Each FilePath in split(SaveFilePath,"/") 
      　　DeclarePath=Replace(DeclarePath&FilePath&"/","//","/")  
      　　if FileObj.FolderExists(Server.MapPath(DeclarePath))=false then 
       　　　　FileObj.CreateFolder(Server.MapPath(DeclarePath))'创建文件夹
      　　end if
     Next
     Set FileObj=nothing
     CreatePath=DeclarePath
  End Function


  '/*
  ' * 功能描述:重命名文件夹
  ' * 输入参数：GetPath——文件夹路径
  ' * 输入参数：OldName——旧的文件夹名称
  ' * 输入参数：NewName——新的文件夹名称
  '*/
  Public Function RenFolder(GetPath,OldName,NewName)
     Dim Fso
     if OldName="" or NewName="" then
      　　exit Function
     else
      　　if OldName=NewName then exit Function
     end if
     SET Fso=Server.CreateObject("Scripting.FileSystemObject")
     if Fso.FolderExists(Server.MapPath(GetPath&NewName)) then
      　　response.write"<script language=javascript>alert('目录已经存在！！');this.history.go(-1);</script>"
      　　response.end()
     end if
     '//旧的文件夹不存在，则创建
     if Not Fso.FolderExists(Server.MapPath(GetPath&OldName)) Then
      　　CreatePath(GetPath&OldName)
     End if
     Fso.MoveFolder Server.MapPath(GetPath&OldName),Server.MapPath(GetPath&NewName)
     set Fso=nothing
     'response.redirect request.ServerVariables("HTTP_REFERER")
  End Function


  '/*
  ' * 功能描述:保存当前文件
  ' * 输入参数：GetPath——文件路径
  ' * 输入参数：GetContent——保存的内容
  ' * 输入参数：GetFile——保存的文件名
  '*/
  Public Function SaveEditFile(GetPath,GetContent,GetFile)
     if GetContent="" or GetFile="" then exit Function
     SET Fso=Server.CreateObject("Scripting.FileSystemObject")
     set CF=Fso.CreateTextFile(Server.mappath(GetPath&GetFile),true)
      CF.write GetContent
      CF.Close
     set CF=nothing
     set Fso=nothing
     'response.redirect request.ServerVariables("HTTP_REFERER")
  End Function
End Class